home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / smaltalk / manchest.lha / MANCHESTER / manchester / 4.1 / Lazy.st < prev    next >
Text File  |  1993-07-24  |  2KB  |  84 lines
  1. "    NAME        Lazy
  2.     AUTHOR        miw@cs.man.ac.uk
  3.     FUNCTION    implements lazy evaluation
  4.     ST-VERSION    4.0 4.1
  5.     PREREQUISITES    
  6.     CONFLICTS
  7.     DISTRIBUTION    world
  8.     VERSION        1
  9.     DATE    10 Nov 1992
  10. SUMMARY Lazy implements lazy objects (which are given a block to compute 
  11. their value, but only do so on demand) MIW.
  12. "
  13. 'From Smalltalk-80, Version 2.2 of July 4, 1987 on 25 February 1988 at 9:51:47 pm'!
  14.  
  15. nil subclass: #Lazy
  16.     instanceVariableNames: 'result done args '
  17.     classVariableNames: ''
  18.     poolDictionaries: ''
  19.     category: 'Kernel-Processes'!
  20. Lazy comment:
  21. 'I represent an execution which may not be required.  I will
  22. not start execution until at least one message has been
  23. received.  The messages sent to me are delayed until execution
  24. has completed.'!
  25.  
  26.  
  27. !Lazy methodsFor: 'initializing'!
  28.  
  29. block: aBlock
  30.     done := false.
  31.     result := aBlock.
  32.     args := #()!
  33.  
  34. block: aBlock value: value
  35.     done := false.
  36.     result := aBlock.
  37.     args := Array with: value!
  38.  
  39. block: aBlock value: value1 value: value2
  40.     done := false.
  41.     result := aBlock.
  42.     args := Array with: value1 with: value2!
  43.  
  44. block: aBlock value: value1 value: value2 value: value3
  45.     done := false.
  46.     result := aBlock.
  47.     args := Array with: value1 with: value2 with: value3!
  48.  
  49. block: aBlock valueWithArguments: anArray
  50.     done := false.
  51.     result := aBlock.
  52.     args := anArray! !
  53.  
  54. !Lazy methodsFor: 'evaluating'!
  55.  
  56. doesNotUnderstand: aMessage
  57.     done ifFalse:    "this really should be a critical region"
  58.              [result := result valueWithArguments: args. done := true].
  59.     ^result perform: aMessage selector withArguments: aMessage arguments! !
  60.  
  61.  
  62.  
  63. !BlockClosure methodsFor: 'lazy evaluation'!
  64.  
  65. lazyValue
  66.     "Return an object that knows how to evaluate me if called on to do so."
  67.     ^Lazy new block: self!
  68.  
  69. lazyValue: value
  70.     "Return an object that knows how to evaluate me if called on to do so."
  71.     ^Lazy new block: self value: value!
  72.  
  73. lazyValue: value1 value: value2
  74.     "Return an object that knows how to evaluate me if called on to do so."
  75.     ^Lazy new block: self value: value1 value: value2!
  76.  
  77. lazyValue: value1 value: value2 value: value3
  78.     "Return an object that knows how to evaluate me if called on to do so."
  79.     ^Lazy new block: self value: value1 value: value2 value: value3!
  80.  
  81. lazyValueWithArguments: anArray
  82.     "Return an object that knows how to evaluate me if called on to do so."
  83.      ^Lazy new block: self valueWithArguments: anArray! !
  84.